---

/*{
	"CREDIT": "mojovideotech",
	"DESCRIPTION": "",
	"CATEGORIES": [],
	"INPUTS": [
		{
			"MAX": [
				2.5,
				2.5
			],
			"MIN": [
				0.1,
				0.1
			],
			"DEFAULT": [
				2,
				1
			],
			"NAME": "phase",
			"TYPE": "point2D"
		},
		{
			"MAX": [
				2,
				2
			],
			"MIN": [
				-2,
				-2
			],
			"DEFAULT": [
				1,
				-0.5
			],
			"NAME": "freqmod",
			"TYPE": "point2D"
		},
		{
			"MAX": 0.999,
			"MIN": 0.001,
			"DEFAULT": 0.111,
			"NAME": "hueA",
			"TYPE": "float"
		},
		{
			"MAX": 0.999,
			"MIN": 0.001,
			"DEFAULT": 0.05,
			"NAME": "hueB",
			"TYPE": "float"
		},
		{
			"MAX": 2,
			"MIN": 0.005,
			"DEFAULT": 0.5,
			"NAME": "brightness",
			"TYPE": "float"
		},
		{
			"MAX": 2,
			"MIN": 0.001,
			"DEFAULT": 0,
			"NAME": "saturation",
			"TYPE": "float"
		},
		{
			"MAX": 4,
			"MIN": 0.5,
			"DEFAULT": 2.25,
			"NAME": "depth",
			"TYPE": "float"
		},
		{
			"MAX": 4,
			"MIN": 0.25,
			"DEFAULT": 1.5,
			"NAME": "rate",
			"TYPE": "float"
		}
	]
}
*/


#ifdef GL_ES
precision highp float;
#endif

// RippleFactory by mojovideotech
// based on:
// http://glslsandbox.com/e#26539.1

// forked from:
// http://glslsandbox.com/e#26152.8
// Description : Array and textureless GLSL 2D/3D/4D simplex 
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : ijm
//     Lastmod : 20110822 (ijm)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com/ashima/webgl-noise
//     Source  : https://github.com/ashima/webgl-noise/blob/master/src/noise3D.glsl


vec3 mod289(vec3 x) {
  return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 mod289(vec4 x) {
  return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 permute(vec4 x) {
     return mod289(((x*34.0)+1.0)*x);
}

vec4 taylorInvSqrt(vec4 r)
{
  return 1.79284291400159 - 0.85373472095314 * r;
}

float snoise(vec3 v)
  { 
  const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
  const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);

// First corner
  vec3 i  = floor(v + dot(v, C.yyy) );
  vec3 x0 =   v - i + dot(i, C.xxx) ;

// Other corners
  vec3 g = step(x0.yzx, x0.xyz);
  vec3 l = 1.0 - g;
  vec3 i1 = min( g.xyz, l.zxy );
  vec3 i2 = max( g.xyz, l.zxy );

  //   x0 = x0 - 0.0 + 0.0 * C.xxx;
  //   x1 = x0 - i1  + 1.0 * C.xxx;
  //   x2 = x0 - i2  + 2.0 * C.xxx;
  //   x3 = x0 - 1.0 + 3.0 * C.xxx;
  vec3 x1 = x0 - i1 + C.xxx;
  vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
  vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y

// Permutations
  i = mod289(i); 
  vec4 p = permute( permute( permute( 
             i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
           + i.y + vec4(0.0, i1.y, i2.y, 1.0 )) 
           + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));

// Gradients: 7x7 points over a square, mapped onto an octahedron.
// The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
  float n_ = 0.142857142857; // 1.0/7.0
  vec3  ns = n_ * D.wyz - D.xzx;

  vec4 j = p - 49.0 * floor(p * ns.z * ns.z); // p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)
  vec4 x_ = floor(j * ns.z);
  vec4 y_ = mod(j,n_); //floor(j - 7.0 * x_ );    // mod(j,N)
  vec4 x = x_ *ns.x + ns.yyyy;
  vec4 y = y_ *ns.x + ns.yyyy;
  vec4 h = 1.0 - abs(x) - abs(y);

  vec4 b0 = vec4( x.xy, y.xy );
  vec4 b1 = vec4( x.zw, y.zw );

  //vec4 s0 = vec4(mod(b0,1.001))*2.0 - 1.0;
  //vec4 s1 = vec4(mod(b1,1.001))*2.0 - 1.0;
  vec4 s0 = floor(b0)*2.0 + 1.0;
  vec4 s1 = floor(b1)*2.0 + 1.0;
  vec4 sh = -step(h, vec4(0.0));

  vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
  vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;

  vec3 p0 = vec3(a0.xy,h.x);
  vec3 p1 = vec3(a0.zw,h.y);
  vec3 p2 = vec3(a1.xy,h.z);
  vec3 p3 = vec3(a1.zw,h.w);

//Normalise gradients
  vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
  p0 *= norm.x;
  p1 *= norm.y;
  p2 *= norm.z;
  p3 *= norm.w;

// Mix final noise value
  vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
  m = m * m;
  return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1), 
                                dot(p2,x2), dot(p3,x3) ) );
}
    
#define PI 3.14159265359

float s(float x, float b) {
	return sin(x * 2. * PI * b) / b;
}

//------------------------------------------------------------------
// begin modified code by mojovideotech
//------------------------------------------------------------------

vec3 hsv2rgb(vec3 c)
{
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xzy + K.xyz) * 6.0 - K.zww);
    return c.z * mix(K.yyy, clamp(p - K.xzy, 0.0, 0.5), c.y);
}

void main( void ) {

	vec2 position = ( gl_FragCoord.xy / vec2(RENDERSIZE.x*phase.x, RENDERSIZE.y*phase.y));
	float scale = depth;
	vec2 midpoint = vec2(freqmod) * scale;
	float x = position.x * scale;
	float y = position.y * scale;
	float r = distance(vec2(x, y), midpoint);
	vec2 tmid = vec2(x, y) - midpoint;
	float theta = atan(tmid.y, tmid.x);
	if (y > midpoint.y) theta = -theta;
	float n = 0.0;
	float q = 0.0;
	x -= midpoint.x;
	y -= midpoint.y;
	float b = snoise(vec3(x, y, (TIME*rate) / 3.333)) * 0.5 + 0.5;
	n = snoise(vec3(pow(b+1.0, r)*scale, x*2.0, (TIME*rate) / 2.718281828459));
	q = snoise(vec3(pow(b+1.0, r)*scale, theta, (TIME*rate) / 1.618033988749));
	n = sin(n)*0.5+0.5;
	n = 0.1 / pow(abs(n), brightness);
	vec3 rgb = hsv2rgb(vec3(hueA, saturation, n));
	rgb -= hsv2rgb(vec3(hueB, saturation, q));

	
	gl_FragColor.rgba = vec4(rgb, 1.0);
}